Le tableau entrées-sorties symétrique de la France

Introduction

Les comptes nationaux se présentent sous la forme d'une masse considérable de chiffres reposant sur des concepts parfois peu naturels, ce qui peut leur donner un aspect quelque peu ésotérique. Pourtant, ils permettent de mieux comprendre l'économie d'économie si l'on sait les exploiter. Notre objectif est ici de fournir à tous ceux qui ne sont pas des experts des outils permettant de les analyser simplement.

Dans ce chapitre, nous allons analyser le tableau entrées-sorties symétrique de la France. Pour cela nous allons réaliser un petit modèle de Leontief en nous appuyant sur deux chapitres de ce site :

• Tableaux des ressources et des emplois
• Introduction à Visual Basic pour Excel

Le premier chapitre nous fournira les bases pour créer un modèle de Leontief, le second nous donnera les outils informatiques pour le mettre en œuvre.

Présentation du tableau entrées-sorties symétrique

Le tableau entrées-sorties symétrique français se distingue principalement du tableau entrées-sorties classique par trois points :

• les emplois sont valorisés au prix de base et non au prix d'acquisition pour que les ressources et les emplois soient valorisés de la même manière ;
• les équilibres ressources-emplois sont réalisés séparément pour les produits locaux et les produits importés ;
• une matrice de production, détaillant la production par branche et par produit, remplace la colonne de production du TES classique.

Le tableau entrées-sorties symétrique se présente sous la forme suivante :

Le tableau entrées-sorties symétrique permet de nombreuses analyses parmi lesquelles nous choisirons d'étudier comment la demande finale est satisfaite par la valeur ajoutée et les importations.

La demande finale, par exemple la consommation finale des ménages, est satisfaite à la fois par la production et les importations. Mais la production nécessite des consommations intermédiaires en produits locaux et importés. La consommation intermédiaire en produits locaux est satisfaite par une production qui nécessite, elle aussi, des consommations intermédiaires en produits locaux et importés. On voit donc qu'il s'agit d'un processus itératif. Pour le résoudre, le modèle de Leontief repose sur une hypothèse de constance des structures par produit et branche de la production, des importations, des consommations intermédiaires et des emplois finals.

Mise en place du modèle

La première étape consiste à récupérer le tableau entrées-sorties symétrique de la France. Pour cela, il faut aller sur le site de l'Insee, puis de taper dans la recherche Tableau entrées-sorties symétrique. Dans la liste qui apparaît, il faut cliquer sur Tableaux de synthèse : TES et TEE puis sur Tableau des entrées-sorties symétrique.

On peut alors télécharger le classeur Excel. Celui-ci a pour nom TEES_2017.xls et se compose de trois feuilles : Présentation du TES symétrique, TES de production domestique, TES des importations. Nous allons sauvegarder ce classeur en tant que classeur prenant en charge les macros, c'est-à-dire avec l'extension .xlsm.

Pour créer notre modèle, nous insérons dans ce classeur deux pages supplémentaires que nous nommons Demande et Resultat. La feuille Demande est destinée à entrer les éléments de la demande finale que nous voulons analyser, elle se présente sous la forme suivante :

La feuille Resultat présente le tableau entrées-sorties symétrique correspondant à la demande finale choisie dans la feuille Demande, elle se présente sous la forme de six blocs correspondant au schéma présenté plus haut.

Nous avons choisi d'élaborer notre modèle en utilisant le langage de programmation Visual Basic pour Excel qui est présenté sur ce site. Le programme ci-dessous peut être copié depuis le navigateur (Edge, FireFox, Chrome, etc.) dans l'éditeur Visual Basic du classeur Excel.

Sub CalculTES()

Dim MatProd(38, 38), MatCIdom(38, 38), MatEmploisDom(38, 11) As Double
Dim DemandeDom(37), DemandeImp(37) As Double
Dim ConsDom(38), ConsImp(38) As Double
Dim MatImport(38, 3), MatCIimport(38, 38), MatEmploisImp(38, 11) As Double
Dim LigneSommeCIdom(37), ColSommeCIdom(37) As Double
Dim LigneSommeCIimp(37), ColSommeCIimp(37) As Double
Dim ProductionBR(37), ProductionPR(37) As Double
Dim StrucLigneProd(37, 37), StrucColCIdom(37, 37), StrucColCIimp(37, 37) As Double
Dim Production(37, 37), CIdom(37, 37), CIimp(37, 37) As Double
Dim TotCI(37), VA(37) As Double

' Saisie du TES
SaisieTES MatProd, MatCIdom, MatEmploisDom, MatImport, MatCIimport, MatEmploisImp, ConsDom, ConsImp, DemandeDom

'Cas où la demande finale est la consommation finale
Set f = ThisWorkbook.Sheets("Demande")
Conso = f.Range("F5")

If IsNumeric(Conso) And Conso <> 0 Then
   For i = 1 To 37
       DemandeDom(i) = ConsDom(i) * Conso / (ConsDom(38) + ConsImp(38))
       DemandeImp(i) = ConsImp(i) * Conso / (ConsDom(38) + ConsImp(38))
   Next i
   f.Range("D5:D42").ClearContents
End If

' Calcul de la structure de la production par branche
For i = 1 To 37
    For j = 1 To 37
       StrucLigneProd(i, j) = MatProd(i, j) / MatProd(i, 38)
    Next j
Next i

'Calcul de la structure des consommations intermédiaires nationales par produit
For j = 1 To 36
    For i = 1 To 37
       StrucColCIdom(i, j) = MatCIdom(i, j) / MatProd(38, j)
    Next i
Next j

'Calcul de la structure des consommations intermédiaires importées par produit
For j = 1 To 36
    For i = 1 To 37
       StrucColCIimp(i, j) = MatCIimport(i, j) / MatProd(38, j)
    Next i
Next j

Ecart = 1
' Début de la boucle d'itérations
Do While Ecart > 0.001
   Pr = Prod
   
   ' Calcul de la colonne des sommes des consommations intermédiaire
   ColSomme CIdom, ColSommeCIdom
   
   ' Calcul de la production totale par produit
   For i = 1 To 37
       ProductionPR(i) = DemandeDom(i) + ColSommeCIdom(i)
   Next i
   
   ' Calcul de la matrice de production en ventilant par branche
   For j = 1 To 37
       For i = 1 To 37
          Production(i, j) = ProductionPR(i) * StrucLigneProd(i, j)
       Next i
   Next j

   'Calcul de la production par branche
   LigneSomme Production, ProductionBR

   'Calcul des consommations intermédiaires nationales
   For i = 1 To 37
       For j = 1 To 37
          CIdom(i, j) = ProductionBR(j) * StrucColCIdom(i, j)
       Next j
   Next i
   Prod = TotLigne(ProductionBR)
   Ecart = Abs(Prod - Pr)
'Fin de la boucle
Loop

'Calcul des consommations intermédiaires importées
For i = 1 To 37
    For j = 1 To 37
       CIimp(i, j) = ProductionBR(j) * StrucColCIimp(i, j)
    Next j
Next i

'Calcul de la ligne des totaux des consommations intermédiaires locales
LigneSomme CIdom, LigneSommeCIdom

'Calcul de la colonne des totaux des consommations intermédiaires importées
ColSomme CIimp, ColSommeCIimp

'Calcul de la ligne des totaux des consommations intermédiaires importées
LigneSomme CIimp, LigneSommeCIimp

'Calcul de la consommation intermédiaire totale et de la valeur ajoutée
For j = 1 To 37
    TotCI(j) =0
    TotCI(j) = LigneSommeCIdom(j) + LigneSommeCIimp(j)
    VA(j) = ProductionBR(j) - TotCI(j)
Next j

' Calcul de la valeur ajoutée du secteur primaire et des importations en produits du secteur primaire
VAprim = 0
For j = 1 To 2
    VAprim = VAprim + VA(j)
    ImpPrim = ImpPrim + LigneSommeCIimp(j) + DemandeImp(j)
Next j
For j = 3 To 18

' Calcul de la valeur ajoutée du secteur secondaire et des importations en produits du secteur secondaire
    VAsec = VAsec + VA(j)
    ImpSec = ImpSec + LigneSommeCIimp(j) + DemandeImp(j)
Next j

' Calcul de la valeur ajoutée du secteur tertiaire et des importations en produits du secteur tertiaire
For j = 19 To 37
    VAter = VAter + VA(j)
    ImpTer = ImpTer + LigneSommeCIimp(j) + DemandeImp(j)
Next j

'Affichage
ScreenUpdating = False
Set f = ThisWorkbook.Sheets("Resultat")

'Affichage de la production
f.Range("D8, AO45").ClearContents
For j = 1 To 37
    For i = 1 To 37
       If Production(i, j) <> 0 Then f.Cells(i + 7, j + 3) = Production(i, j)
    Next i
Next j
For j = 1 To 37
If ProductionBR(j) <> 0 Then f.Cells(45, j + 3) = ProductionBR(j)
Next j
For i = 1 To 37
    If ProductionPR(i) <> 0 Then f.Cells(i + 7, 41) = ProductionPR(i)
Next i

'Affichage des consommations intermédiaires locales
f.Range("AS8, CD45").ClearContents
For j = 1 To 37
    For i = 1 To 37
       If CIdom(i, j) <> 0 Then f.Cells(i + 7, j + 44) = CIdom(i, j)
    Next i
Next j
For j = 1 To 37
If LigneSommeCIdom(j) <> 0 Then f.Cells(45, j + 44) = LigneSommeCIdom(j)
Next j
For i = 1 To 37
    If ColSommeCIdom(i) <> 0 Then f.Cells(i + 7, 82) = ColSommeCIdom(i)
Next i

'Affichage des consommations intermédiaires importées
f.Range("AS54, CD91").ClearContents
For j = 1 To 37
    For i = 1 To 37
       If CIimp(i, j) <> 0 Then f.Cells(i + 53, j + 44) = CIimp(i, j)
    Next i
Next j
For j = 1 To 37
If LigneSommeCIimp(j) <> 0 Then f.Cells(91, j + 44) = LigneSommeCIimp(j)
Next j
For i = 1 To 37
    If ColSommeCIimp(i) <> 0 Then f.Cells(i + 53, 82) = ColSommeCIimp(i)
Next i

'Affichage de la demande finale
f.Range("CH8, CH45").ClearContents
For i = 1 To 37
    f.Cells(i + 7, 86) = DemandeDom(i)
Next i
f.Range("CH54, CH91").ClearContents
For i = 1 To 37
f.Cells(i + 53, 86) = DemandeImp(i)
Next i

'Affichage des totaux
f.Range("AS93, CD95").ClearContents
For j = 1 To 37
    If TotCI(j) <> 0 Then f.Cells(93, j + 44) = TotCI(j)
Next j
For j = 1 To 37
    If VA(j) <> 0 Then f.Cells(95, j + 44) = VA(j)
Next j
f.Cells(45, 41) = TotLigne(ProductionBR)
f.Cells(45, 82) = TotLigne(LigneSommeCIdom)
f.Cells(91, 82) = TotLigne(LigneSommeCIimp)
f.Cells(93, 82) = TotLigne(TotCI)
f.Cells(95, 82) = TotLigne(VA)
f.Cells(45, 86) = TotLigne(DemandeDom)
f.Cells(91, 86) = TotLigne(DemandeImp)
f.Cells(93, 86) = f.Cells(45, 86) + f.Cells(91, 86)

'Affichage du résultat dans la feuille Demande
Set g = ThisWorkbook.Sheets("Demande")
g.Range("G10") = TotLigne(VA)
g.Range("G11") = VAprim
g.Range("G12") = VAsec
g.Range("G13") = VAter
g.Range("G14") = TotLigne(LigneSommeCIimp) + TotLigne(DemandeImp)
g.Range("G15") = ImpPrim
g.Range("G16") = ImpSec
g.Range("G17") = ImpTer

ScreenUpdating = True

End Sub

---

Sub SaisieTES(MatProd, MatCIdom, MatEmploisDom, MatImport, MatCIimport, MatEmploisImp, ConsDom, ConsImp, DemandeDom)
Set f = ThisWorkbook.Sheets("TES de production domestique")
Set g = ThisWorkbook.Sheets("TES des importations")
Set h = ThisWorkbook.Sheets("Demande")
For i = 1 To 38
    For j = 1 To 38
       MatProd(i, j) = f.Cells(i + 10, j + 3)
       MatCIdom(i, j) = f.Cells(i + 10, j + 44)
       MatCIimport(i, j) = g.Cells(i + 10, j + 9)
    Next j
Next i
For i = 1 To 38
    For j = 1 To 11
       MatEmploisDom(i, j) = f.Cells(i + 10, j + 85)
       MatEmploisImp(i, j) = g.Cells(i + 10, j + 50)
    Next j
Next i
For i = 1 To 38
    For j = 1 To 3
       MatImport(i, j) = g.Cells(i + 10, j + 3)
    Next j
Next i
For i = 1 To 38
    ConsDom(i) = f.Cells(i + 10, 86)
Next i
For i = 1 To 38
    ConsImp(i) = g.Cells(i + 10, 51)
Next i
For i = 1 To 37
    DemandeDom(i) = h.Cells(i + 4, 4)
Next i
End Sub

---

Sub LigneSomme(A, LigneA)
finl = UBound(A, 1)
finc = UBound(A, 2)
For j = 1 To finc
    LigneA(j) = 0
    For i = 1 To finl
       LigneA(j) = LigneA(j) + A(i, j)
    Next i
Next j
End Sub

---

Sub ColSomme(A, ColA)
finl = UBound(A, 1)
finc = UBound(A, 2)
For i = 1 To finl
    ColA(i) = 0
    For j = 1 To finc
       ColA(i) = ColA(i) + A(i, j)
    Next j
Next i
End Sub

---

Function TotLigne(A)
debl = LBound(A)
finl = UBound(A)
TotLigne = 0
For j = debl To finl
    TotLigne = TotLigne + A(j)
Next j
End Function

---

On a ajouté un bouton dans la feuille Demande pour lancer le programme.

Résultats

Pour déterminer la décomposition de la dépense de consommation finale des ménages en valeur ajoutée et importations, il faut entrer un nombre dans la cellule F5 puis cliquer sur le bouton. Ainsi, si l'on entre une dépense de consommation finale de 1000 on trouve le résultat suivant :

Résultat

Valeur ajoutée    Secteur primaire    Secteur secondaire    Secteur tertiaire	749,1 23,1 87,4 638,6
Importations    Secteur primaire    Secteur secondaire    Secteur tertiaire	250,9 12,1 163,8 74,9
Total	1 000,0

La valeur ajoutée qui est présentée ici ne correspond pas exactement à la définition officielle de la valeur ajoutée puisque les consommations intermédiaires ne sont pas valorisées aux prix d'acquisition mais aux prix de base.

Si l'on ne met pas de nombre dans la cellule F5, on peut calculer la décomposition en valeur ajoutée et importations d'une demande finale en produits locaux. Par exemple, si l'on entre 1000 comme demande finale en produits chimiques locaux, on obtient le résultat suivant :

Résultat

Valeur ajoutée    Secteur primaire    Secteur secondaire    Secteur tertiaire	642,6 10,8 447,3 184,5
Importations    Secteur primaire    Secteur secondaire    Secteur tertiaire	357,4 3,2 329,3 24,8
Total	1000,0

On peut également voir l'ensemble du tableau entrées-sorties symétrique détaillé dans la feuille Résultat.

Le tableau ci-dessous montre comment une demande en produits locaux de 100 se décompose en valeur ajoutée et importations :

Produits locaux	Valeur ajoutée	Importations
AGRICULTURE, SYLVICULTURE ET PÊCHE	80	20
INDUSTRIES EXTRACTIVES	75	25
FABRICATION DE DENRÉES ALIMENTAIRES, DE BOISSONS ET DE PRODUITS À BASE DE TABAC	75	25
FABRICATION DE TEXTILES, INDUSTRIES DE L'HABILLEMENT, INDUSTRIE DU CUIR ET DE LA CHAUSSURE	63	37
TRAVAIL DU BOIS, INDUSTRIES DU PAPIER ET IMPRIMERIE	70	30
COKÉFACTION ET RAFFINAGE	27	73
INDUSTRIE CHIMIQUE	64	36
INDUSTRIE PHARMACEUTIQUE	72	28
FABRICATION DE PRODUITS EN CAOUTCHOUC, EN PLASTIQUE ET D'AUTRES PRODUITS MINÉRAUX NON MÉTALLIQUES	69	31
MÉTALLURGIE ET FABRICATION DE PRODUITS MÉTALLIQUES, HORS MACHINES ET ÉQUIPEMENTS	65	35
FABRICATION DE PRODUITS INFORMATIQUES, ÉLECTRONIQUES ET OPTIQUES	70	30
FABRICATION D ÉQUIPEMENTS ÉLECTRIQUES	61	39
FABRICATION DE MACHINES ET ÉQUIPEMENTS N.C.A.	64	36
FABRICATION DE MATÉRIELS DE TRANSPORT	52	48
AUTRES INDUSTRIES MANUFACTURIÈRES ; RÉPARATION ET INSTALLATION DE MACHINES ET D'ÉQUIPEMENTS	70	30
PRODUCTION ET DISTRIBUTION D'ÉLECTRICITÉ, DE GAZ, DE VAPEUR ET D'AIR CONDITIONNÉ	70	30
PRODUCTION ET DISTRIBUTION D'EAU ; ASSAINISSEMENT, GESTION DES DÉCHETS ET DÉPOLLUTION	83	17
CONSTRUCTION	78	22
COMMERCE ; RÉPARATION D'AUTOMOBILES ET DE MOTOCYCLES	85	15
TRANSPORTS ET ENTREPOSAGE	83	17
HÉBERGEMENT ET RESTAURATION	85	15
ÉDITION, AUDIOVISUEL ET DIFFUSION	82	18
TÉLÉCOMMUNICATIONS	83	17
ACTIVITÉS INFORMATIQUES ET SERVICES D'INFORMATION	89	11
ACTIVITÉS FINANCIÈRES ET D'ASSURANCE	90	10
ACTIVITÉS IMMOBILIÈRES	97	3
ACTIVITÉS JURIDIQUES, COMPTABLES, DE GESTION, D'ARCHITECTURE, D'INGÉNIERIE, DE CONTRÔLE ET D'ANALYSES TECHNIQUES	87	13
RECHERCHE-DÉVELOPPEMENT SCIENTIFIQUE	86	14
AUTRES ACTIVITÉS SPÉCIALISÉES, SCIENTIFIQUES ET TECHNIQUES	83	17
ACTIVITÉS DE SERVICES ADMINISTRATIFS ET DE SOUTIEN	89	11
ADMINISTRATION PUBLIQUE ET DÉFENSE - SÉCURITÉ SOCIALE OBLIGATOIRE	94	6
ENSEIGNEMENT	95	5
ACTIVITÉS POUR LA SANTÉ HUMAINE	91	9
HÉBERGEMENT MÉDICO-SOCIAL ET SOCIAL ET ACTION SOCIALE SANS HÉBERGEMENT	95	5
ARTS, SPECTACLES ET ACTIVITÉS RÉCRÉATIVES	87	13
AUTRES ACTIVITÉS DE SERVICES	88	12
ACTIVITÉS DES MÉNAGES EN TANT QU'EMPLOYEURS ; ACTIVITÉS INDIFFÉRENCIÉES DES MÉNAGES EN TANT QUE PRODUCTEURS DE BIENS ET SERVICES POUR USAGE PROPRE	100	0

Auteur : Francis Malherbe